S2T2

Jim Randell 12:50 pm on 5 November 2019 Permalink Reply
Tags: by: Jean Harrison ( 2 ), corrected ( 10 ), flawed ( 53 )   

• 

  Jim Randell 2:22 pm on 5 November 2019 Permalink | Reply

  I wrote a program to solve the puzzle as originally stated (without the additional text) and found 15 solutions.

  So I created a MiniZinc model that makes it easy to play around with variations on the puzzle.

  When the constraints arising from the missing text are incorporated we get a single solution.

  %#! minizinc -a
  
  % grandpa and grandma are aged between 51 and 69
  var 51..69: gp;
  var 51..69: gm;
  
  % but the total is not more than 120
  constraint not(gp + gm > 120);
  
  % son's age
  var 18..51: son;
  
  % kids ages (0 for no kid)
  array[1..10] of var 0..16: kids;
  
  % kids are descending order, and all different
  constraint forall (i in 2..10) (kids[i] > 0 -> kids[i - 1] > kids[i]);
  
  % son + total of kids ages = gm [originally was = gp]
  constraint son + sum(kids) = gm;
  
  % son + total of kids ages in 1 year = gp, so: gp - gm = number of children
  % [originally this condition was omitted]
  constraint sum (i in 1..10) (kids[i] > 0) = gp - gm;
  
  % exactly 1 kid divides gp
  constraint sum (i in 1..10) (kids[i] > 1 /\ gp mod kids[i] = 0) = 1;
  
  % but exactly 3 kids divide gp in 1 year
  constraint sum (i in 1..10) (kids[i] > 0 /\ (gp + 1) mod (kids[i] + 1) = 0) = 3;
  
  % and exactly 1 kid divides gm in 1 year
  constraint sum (i in 1..10) (kids[i] > 0 /\ (gm + 1) mod (kids[i] + 1) = 0) = 1;
  
  % also the number of kids + 1 divides into gp in 1 year
  constraint (gp + 1) mod (1 + sum (i in 1..10) (kids[i] > 0)) = 0;
  
  % (son + 1) divides gp
  constraint gp mod (son + 1) = 0;
  
  % at least 16 years between generations
  constraint son + 16 < min([gp, gm]);
  constraint max(kids) + 16 < son;
  
  solve satisfy;
  

  And we can format the output with Python 3 by using the minizinc.py wrapper:

  from minizinc import MiniZinc
  
  for (gp, gm, son, kids) in MiniZinc("teaser508.mzn").solve(result="gp gm son kids"):
    kids = list(x for x in kids.values() if x > 0)
    print(f"Grandpa = {gp}; Grandma = {gm}; Son = {son}; Children = {kids}")
  

  So the answer to the corrected puzzle is:

  Solution: Grandpa = 62; Grandma = 56; Son = 30; Children = 8, 6, 5, 4, 2, 1.

  Without the constraints to enforce a 16 year gap between generations we can have a further solution (with 7 children):

  Grandpa = 63; Grandma = 56; Son = 20; Children = 15, 6, 5, 4, 3, 2, 1

  LikeLike