S2T2

Jim Randell 9:11 am on 1 October 2019 Permalink Reply
Tags: by: R Brain ( 3 )   

• 

  Jim Randell 9:13 am on 1 October 2019 Permalink | Reply

  I assumed the exams are marked out of 100, and only whole numbers of marks are awarded.

  I made a MiniZinc model for the puzzle. It finds a single solution in 121ms.

  %#! minizinc --solver chuffed --all
  
  include "globals.mzn";
  
  % label the boys
  set of int: Boys = 1..7;
  int: A = 1;
  int: B = 2;
  int: C = 3;
  int: D = 4;
  int: E = 5;
  int: F = 6;
  int: G = 7;
  
  % places for each boy in each subject
  array [Boys] of var 1..7: pPh;
  array [Boys] of var 1..7: pCh;
  
  constraint all_different(pPh);
  constraint all_different(pCh);
  
  % marks for each boy in each subject
  array [Boys] of var 0..100: mPh;
  array [Boys] of var 0..100: mCh;
  
  constraint forall (x, y in Boys where x != y) ((pPh[x] < pPh[y]) -> (mPh[x] > mPh[y]));
  constraint forall (x, y in Boys where x != y) ((pCh[x] < pCh[y]) -> (mCh[x] > mCh[y]));
  
  % given values
  constraint pPh[A] = 5;
  constraint pCh[B] = 2;
  constraint pPh[E] = 3;
  constraint pCh[G] = 5;
  constraint mPh[D] = 70;
  constraint mCh[F] = 67;
  constraint mPh[G] = 71;
  
  % total marks is 1023
  constraint sum (x in Boys) (mCh[x] + mPh[x]) = 1023;
  
  % "the pupils finished in alphabetical order by total marks"
  constraint decreasing (x in Boys) (mPh[x] + mCh[x]);
  
  % "there were no ties in either subject, or overall"
  constraint all_different(mPh);
  constraint all_different(mCh);
  constraint all_different (x in Boys) (mPh[x] + mCh[x]);
  
  % "no pupil occupied the same place in both subjects"
  constraint forall (x in Boys) (pPh[x] != pCh[x]);
  
  % "C placed higher in Chemistry than Physics"
  constraint pCh[C] < pPh[C];
  
  solve satisfy;
  

  Solution: Charley got 73% in Physics and 75% in Chemistry.

  Here is the complete table:

  

  LikeLike